Macroいろいろ（06/21Update）
WoW関連のことでそこそこ詳しく調べたり実践したりしているが、まだここで書いていないことって何かないだろうかと考えて、Macroというのがあったので記事を作ってみる。今後Macro関連のネタ・実用例等ここに集約していく予定。Macro用の公式リファレンスというのがあったらいいと思うのだが、少なくとも私が知る限りではない。なのでたいてい私はWikiのこのページをリファレンス代わりに使っている。
かなりの制限はあるとはいえ、WoWのMacroは小さなプログラムと言って差し支えないと思う。よってプログラミングについて少し知っているとかなり飲み込みやすい。もちろん、全然知らなくてもちょっと書いてみればすぐ慣れてくる。
最初に免責事項として書いておくと、Macroを工夫することでプレイの快適性・利便性は多かれ少なかれ向上する。それは保証できる。が、Macroを使うことでエンドコンテンツにおけるパフォーマンス（RaidでのDPS/HPSやらArenaの勝率やらRatingやら）が確実に向上するかといえば、それは保証できないので悪しからず*1。ここで私は結構複雑なMacroも書いていくつもりだが、実際世界にはMacroなんて最低限の機能のものをぽつぽつ用意しているだけでも驚くほど上手にプレイしている人がたくさんいる。半分趣味の世界なのでそこはよろしく。
ほかにもペット関連やターゲット関連等、かなりいろいろある。
かなりの制限はあるとはいえ、WoWのMacroは小さなプログラムと言って差し支えないと思う。よってプログラミングについて少し知っているとかなり飲み込みやすい。もちろん、全然知らなくてもちょっと書いてみればすぐ慣れてくる。
最初に免責事項として書いておくと、Macroを工夫することでプレイの快適性・利便性は多かれ少なかれ向上する。それは保証できる。が、Macroを使うことでエンドコンテンツにおけるパフォーマンス（RaidでのDPS/HPSやらArenaの勝率やらRatingやら）が確実に向上するかといえば、それは保証できないので悪しからず*1。ここで私は結構複雑なMacroも書いていくつもりだが、実際世界にはMacroなんて最低限の機能のものをぽつぽつ用意しているだけでも驚くほど上手にプレイしている人がたくさんいる。半分趣味の世界なのでそこはよろしく。
基本
Macroというのは、要はスラッシュコマンドの組み合わせだ。チャット入力欄を開いて、「/xxxx」と打ち込むことで何か変なことができるあれを、改行を含めて事前に書いて作っておき、アクションバーに置いておくことで好きな時に何度でも使える。多くのことができるわけだが、そのどれもこれもスラッシュコマンドと条件（Conditional）の組み合わせで作れる。MacroウィンドウはEscメニューからか、/mで呼び出せる。またデフォルトでは、チャット入力欄を開かない状態でただ/キーを押すと、先頭に/が入力された状態でチャット入力欄が開くので一緒に覚えておくと便利。
スラッシュコマンド
スラッシュコマンドはチャット入力欄にそのまんま書いてEnter押せばMacroとして保存していなくても大抵使える。主に戦闘関連でよく使うものを列挙しておく。各コマンド使用の際の具体的な文法などはあとで挙げる例を見るかWiki参照。
| /cast,/use | スキルやアイテムを使う。スキルに対して/use、アイテムに対して/castでも問題なく使えるので、文字数が惜しいときは/useを使えば数文字稼げる。ペットのスキルもこれで使える。 |
| /castsequence | カンマ区切りでいくつかのスキルを列挙することで、最初に挙げられたスキルから順番に使っていく。/usesequenceというのはなぜかない。 |
| /castrandom,/userandom | /castsequenceと同じようにスキルを列挙しておくと、列挙された中からランダムで使う。 |
| /equip,/equipslot,/equipset | 指定したアイテム（/equipsetの場合はアイテムセット）を装備する。武器やTrinket、指輪などは/equipslotでスロットも指定できる。 |
| /target,/tar,/cleartarget | 指定した対象をターゲットする。/cleartargetで解除する。何気に大事。 |
| /focus,/clearfocos | 指定した対象をフォーカスに入れる。/clearfocusで解除。 |
| /startattack,/stopattack | AutoAttackやAutoShotを開始・停止する。 |
| /petattack,/petfollow | ペットの攻撃開始・停止を指示。 |
| /stopcasting | 現在のCastを止める。 |
| /dismount | マウントから降りる。 |
| /cancelaura | 指定したBuffを解除する。BuffFrameでのアイコン右クリックと同じ。 |
| /stopmacro | Macroをその行で止める。後述の条件と一緒に使う。 |
| /script,/run | Luaスクリプトを実行する。 |
条件（Conditional）
スラッシュコマンドのあとにはたいていスキルや対象の名前などを入力することになるが、その前に半角角カッコで囲んでいろいろと条件を指定することができる。
/cast [@mouseover,harm,nodead] Polymorph
こんな感じ。指定した条件に合致した場合のみ、コマンドが実行される。上の例だと、カーソルを合わせた対象（@mouseover）が攻撃可能（harm）な相手で、かつ死んでいなかった（nodead）ならPolyする。指定できる条件の種類もかなり多く全部覚えるのは大変。カンマ区切りでいくつでも重ねることができ、その場合すべての条件に合致する場合のみコマンドが実行される*2。カッコで囲んだ条件セットを複数用意することもできる。
/cast [@focus,harm,nodead][@mouseover,harm,nodead][@tar,harm,nodead] Polymorph
こうした場合、書かれた順に条件を判定していって、合致した条件のもとでコマンドを実行する。すべて合致しなかったら当然何も実行しない。言い換えれば条件を書く順番を変えることで、優先順位をつけることもできる。また、主に/castなどのコマンドでは、条件に応じて別のスキルを使用させるように分岐させることもできる。その場合セミコロンを使って、
/cast [mod:shift] Bind Elemental;Hex
のように書く。この場合、Shiftキーを押している（mod:shift）ならBind Elementalを使用し、そうでなかったらHexを使用する。単純に行を分けて、
/cast [mod:shift] Bind Elemental
/cast [nomod:shift] Hex
と書いても同じ内容になるが、/castなどのコマンドなら大抵の場合文字数の節約になる。こちらもセミコロンを入れさえすれば255文字の範囲内でいくつでも分岐させられるので、いろいろな条件にいろいろなスキルを対応させる1ボタンMacroになる*3。
以上が条件の使い方。以下によく使うものをリストアップ。
| @ target= | ターゲット指定ができる。target/focus/mouseover/arena1/party2/raid3といった呼び出し方に対応しているほか、Raid/Partyメンバーであれば具体的な名前でもいい（例：@Gadagarr）。 |
| no | ほかの条件の頭にnoをつけると、否定になる。たいていの条件に対して使える。 |
| mod:shift/ctrl/alt | 修飾キーを押した場合。複数修飾キー同時押しは、「mod:ctrl,mod:shift」と書いてもいいが、「mod:ctrlshift」「mod:ctrlaltshift」のような短縮形が実は用意されている。 |
| exists | @ |
| harm,help,raid,party,dead | existsのより具体的なバージョン。順に「敵なら」「味方なら」*4「Raid(Party)メンバーなら」「Partyメンバーなら」「死んでいるなら」の意。 |
| group:raid/party | 自分がraid/partyに入っている場合。単にgroupと書いた場合partyと同義。BGグループは厳密にはRaidではないが、多分この条件には合致したはず。 |
| spec:1/2 | タレントがプライマリ/セカンダリの場合。 |
| stance:1/2/3/.../n | 「form:」でも同じ。指定したスタンスの場合。Warrのスタンスと同じ位置にバーが出ても、この条件でスタンス扱いにならないクラスもある*5。各クラスで、番号がどのスタンスに対応しているかはWiki参照。 |
| pet: | 指定した名前・種類のペットが呼び出してある場合。単にpetと書いた場合とにかく何か出してある場合を指す。 |
| equipped: | 「worn:」でも同じ（こっちのほうがだいぶ短いのでおすすめ）。特定の種類のアイテムを装備している場合。[equipped:Shields]など。具体的なアイテムの名前は指定できない。アイテム種別の一覧はWikiのこのページ参照。 |
| channeling: | 特定のスペルをチャネリングしている場合。チャネリング中断防止に使う。 |
| combat | 戦闘中の場合。 |
| indoors,outdoors | 屋内か屋外か。マウントできるか否かと言い換えてもだいたい同じ。 |
| flyable | 飛べる場合。Cold Weather Flyingを持っていない状態でNorthrendに行った場合などもこの条件に当てはまってしまうので注意。 |
| mounted,swimming,flying | それぞれマウントしている、泳いでいる、飛んでいる場合。Flight Formがmounted扱いになるかどうかは私は知らない。 |
Tipsとして、コロンのあとにさらに何かしらの指定をするタイプの条件では、スラッシュ区切りで複数の場合を同時に指定できる。例：[stance:1/3]（Warrなら、BattleもしくはBerserkerStanceの場合、の意味）。
その他
#showtooltip
Macroの一番上の行にこう書いておくと、条件分岐に応じたツールチップを出せる。また、Macroのアイコンを選ぶとき、アイコンリストの一番左上にある「？」アイコンを選んでおくと、条件分岐に応じてアイコンも勝手に変化する。対応するアイコンが存在しないコマンド(/petattackなど)だと「？」のままなので、美意識と自分にとっての分かりやすさに応じて使い分けよう。
/castコマンドを複数並べた場合の挙動については注意が必要。
/cast Colossus Smash
/cast Mortal Strike
/cast Overpower
というようにスキルを並べても、GCDをトリガーするスキル同士では同時使用は当然できず、最初の行のみ実行して止まる。逆に言うと、Off-GCDのスキル同士、あるいはGCDスキルひとつとOff-GCDスキル複数の組み合わせであれば、上のように書いて同時使用も当然可能であり、状況によってはかなり便利である。
また、「一番上がCDなら勝手に次に進むんじゃね？」と一瞬思いたくなるのもわかるが、残念ながら最初の行のコマンドがスキルに対するNot ReadyやNeed More Manaなどのエラーで失敗した場合、Macro自体もそこで停止する。同じような発想で「/castrandomにローテスキルを放り込めば勝手に使えるの選んでくれるんじゃね？」というのも残念ながら機能しない。一般的に言って、そういったプレイを簡単にし過ぎる1ボタンMacroは作れないようになっていると考えていい。/castsequenceを使ったMacroなら、上手く作ればそこそこ近いものがつくれなくもないものの、たいていの場合プレイの柔軟性やイレギュラーへの対応を犠牲にすることになる。
装備品のUse効果を使いたい時など、アイテム名を直接書く以外に、スロットに割り当てられている番号を指定する書き方もできる（InventorySlotId）。EngのTinker用Macroや/equipslotコマンドで使われるので、Main-hand=16、Off-hand=17、Ring=11/12、Trinket=13/14、Hands=10、Waist=6、Back=15あたりが頻出だ。また、バッグの中の特定のアイテムを使用・装備したい時は、
/use 0 1
のように書くことができる。最初の数字（0〜4）でバッグを指定し、次の数字（1〜）でバッグ内のスロットを上・左から順に指定できる。
Macroの特定の行を一時的に無効化したい、というような場合、行頭に「#」を入力することでその行がコメントアウトされる。
#/use Fireball
/use Arcane Blast
上のように書いたMacroなら、Arcane Blastを撃つ。
WarriorMacro
ここからは、私が実際にWarrやShmで使っているMacroを例として挙げていく。
- テンプレ攻撃Macro
#showtooltip
/startattack
/use Bloodthirst
/use [nostance:3]Berserker Stance
こういうのはよく作る。/startattackの仕様として、一番近い敵を勝手にターゲットする（TargetNearestEnemy）機能があるので、MeleeRangeに立ってこのMacroを連打すれば、ターゲットに失敗したりカーソルを見失ったりしてもとりあえず殴ってくれる。スタンスも勝手に直す。
- メインスキル
/tar Burning Tendons
/stopcasting
/startattack
/use [mod:shift]Rend;[spec:2]Devastate;Bloodthirst
/use [spec:1]Berserker Stance;Defensive Stance
/equipslot [spec:1,worn:Shields]17 Experimental Specimen Slicer
/changeactionbar 1
1つ上のMacroをいじったもの。Specによってスキル・スタンスを変えているほか、Shift押しでRendも使う（ただしFuryの場合、Berserker StanceからRendは使えないので主にProt用。Armsならこの書き方でそのまま使える）。/stopcastingはSlamの誤Castなどを中断する。その他、Off-Handに盾を持ったままの場合（Shield Wall後など）このMacroを押せば武器に戻す。また、アクションバーのページング機能を使っているなら、裏ページ（Actionbar1以外）を出した状態でこれを押せば表ページに戻る。字数の関係で#showtooltipは削った。
/tar Burning TendonsはDSのSpine戦でキーになる。ただしこの書き方はTendonから距離があるとうまくターゲットしてくれないことがあるらしく、RangeDPSには/tar Boss2が推奨されている。が、/tar Boss2は消しておくのを忘れると別のボスにそのまま行ってしまったときおかしなことになりやすいので、メインで使うMacroに書き加えるのでなく、ターゲット専用Macroにしておくのが無難。
- CSとCDバースト
#showtooltip
/tar Burning Tendons
/startattack
/use [mod:ctrl,combat,group:raid]Golemblood Potion
/use [mod:shift,spec:1]14
/use [mod:shift]Recklessness
/use [mod:shift]Death Wish
/use Colossus Smash
/use Inner Rage
/use Berserker Stance
/use [spec:1]10
Furyなら、EngのSynapseを常にCSに合わせる。Inner Rageが上がっている場合も一緒に使う。スタンスも直す（Armsの場合でも、CS直後には基本的にMSを入れるはずなので、この方式が使える）。Shift押しでDW/Reckも合わせ、Furyなら下スロットに装備したDPSUseTrinket（T13だとVPで買えるものなど）も使う。さらにCtrl押しでRaidならPotも使える。DW効果時間中にCSコンボを2回入れたい都合上、用意しておくといろいろはかどる。
- Shout/PrePotting
#showtooltip
/startattack
/use [mod:ctrl,nocombat,group:raid]Golemblood Potion
/use [mod:shift,spec:1][nomod:shift,spec:2]Commanding Shout;Battle Shout
FuryのときはBattleShout、ProtのときはCommandingShoutを使い、逆を使いたい時はShiftで変える。Raidに入っていて、戦闘開始前にctrl押しで使うとPrePotする。
- Warbringer
#showtooltip
/cast [mod:shift,@focus,raid][@mouseover,raid,nodead][raid,nodead]Intervene
/castsequence [mod:shift,@focus,harm][@mouseover,harm,nodead][]reset=15 Charge,Intercept,Charge
Protでの連続ChargeMacro。/castsequenceはreset=nパラメータをこのように置くことで、Macroが最後に呼び出されてからn秒たったら先頭に戻すことができる。ほかに、reset=combat/target/shift等も指定できる。/castsequenceの弱点として、コマンドの成功・失敗に関係なくMacroが呼び出されるたびにresetカウンタが元に戻ってしまうため、時々きれいにつながらないことがある。とはいえだいたいの場合は機能する。
ちなみに、条件セットの最後に空の条件セット[]を置くと、すべての条件に合致しなかった場合でもとりあえずMacroの内容を表示する、デフォルト選択肢の役割を果たす。
- Prot用Charge
#showtooltip
/use [mod:shiftctrl,@focus,harm][mod:ctrl,@mouseover,harm,nodead][mod:ctrl]Intercept;[mod:shift,@focus,raid][@mouseover,raid,nodead][raid]Intervene;[mod:shift,@focus,harm][@mouseover,harm,nodead][]Charge
上のWarbringerMacroが不安定で好きになれない場合は、このように修飾キーとターゲット種別で分けたMacroがおすすめ。下のFury用Macroの焼き直し。
- Fury用Charge
#showtooltip
/use [form:3,mod:shift,@focus][form:3,@mouseover,harm,nodead][form:3]Intercept;[form:2,mod:shift,@focus][form:2,@mouseover,raid,nodead][form:2]Intervene;[@mouseover,harm,nodead][]Charge
各スタンスで使えるFocus/Mouseover/TargetChargeを1Macroに統一しただけ。FuryはChargeを戦闘中使えないのでFocusChargeは用意していない。Armsなら、Chargeのスタンス制限がなく、戦闘中使えて、かつInterceptを使わなくなったので、「form:2,@mouseover,raid,nodead」といった感じにDefensive Stanceかつ味方ターゲットな場合だけInterveneできるよう分岐を用意しておけば、あとはChargeについてだけ書けばいい。各スタンスバーの同じ位置に登録しておくと楽。
- 5min CD
#showtooltip
/use [mod:shift]Retaliation;[spec:1]Shield Wall;[spec:2]Recklessness
#/equip [nomod:shift,spec:1]Ruthless Gladiator's Slicer
/equip [nomod:shift,spec:1]Cataclysmic Gladiator's Shield Wall
各種5minCDを使い分けるMacro。いずれのSpecでもShift押しでRetaliationを使い、それ以外はDPSならShield Wallを、TankならReckを使う。この場合DPSでReck、TankでSWを使うボタンは別で用意しておくこと。/equip以下は盾装備コマンドで、DPS時に呼び出されるが、仕様上盾を装備していない状態からこのMacroを1プレスしてもSWを使うことはできない（/equipを/useより前に書いても同じ）。装備指定条件のあるスキルが装備変更後に使用可能になるまでに若干のLagがある、及び戦闘中の場合Main-hand/Off-hand/Rangedスロットの武器を変更するとGCDがトリガーされるため。Shield Wallに関して言えば、これ自体はGCD外のスキルなので前者の条件一致Lagが原因になっている。要は連打してくださいという話。
2行目がコメントアウトされているがこれは1H武器を装備するコマンドで、2H武器を片手で持てないArmsの場合入れておく必要がある。
ShamanMacro
- Interrput
#showtooltip
/stopcasting
/cast [mod:shift,@focus,harm][@mouseover,harm,nodead][]Wind Shear
今や基本中の基本。ただ、通信状況や押したタイミングによっては/stopcastingがあってもうまくいかないことがあるらしい？
- EnhのPet管理
#showtooltip
/cast [pet,mod:shift]Spirit Walk;[pet,mod:ctrl]Twin Howl;[pet,@mouseover,harm,nodead][pet]Bash
/cast [nopet]Feral Spirit
PvPをやりだすとこういうのもほしくなってくる。MageでFrostをやる時も似たようなMacroを使っている。
- RestoでESを入れた相手を自動でFocusする
#showtooltip
/cast [mod:shift,mod:ctrl,@mouseover,help][mod:shift,@player][@focus,help][@mouseover,help][]Earth Shield
/clearfocus [@focus,dead][mod:shift,mod:ctrl,@mouseover,help]
/stopmacro [@focus,help]
/focus [@mouseover,help][help]
正直言って、自分でもあまり良い方法ではないと感じているのだが、楽なので使っている。ESを入れた相手をFocusし、その後だれをタゲっていても常にESは最初Focusした相手に入れる。Shift/Ctrl同時押しでES対象とFocusを同時変更。Shiftで自分にES。
- Restoでのヒール優先付け
#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead][@target,help,nodead][@focus,help][]Healing Wave
上のESMacroと合わせて使っている。Shiftで自分に、そのほかはMouseover→Target→Focusの順で優先的にヒール。とりあえずTankにはヒールできるように、というのがこのMacroの方針というか、思想。もう一度書くが、個人的に楽なので使っているだけで、あまり良い方法ではないと思う。こういうこともできる、程度に。
- AnkhのCD表示
#showtooltip Reincarnation
パッシブスキルもこのように書くとバー上に表示だけさせることができるので、CDを見ることができる。OmniCCなどを使っているならより見やすい。
その他のMacro
- マウント4.3（with釣り）
#showtooltip
/use [noflying,nocombat,nomod,worn:Fishing Poles]Fishing;[button:2][mod:alt][nomod:shift/ctrl,flyable,noswimming]Corrupted Fire Hawk;[mod:ctrl,nomod:shift][nomod:shift,swimming]Sea Turtle;Mechano-Hog
状況にあったものを勝手に出す。釣竿を装備していて、戦闘中でなく、着地している場合は釣りボタンになる。各種修飾キーで分岐するようになっている。[button:1/2]ではマウスの左クリック/右クリックも指定できる。水面近くで泳いでいる状態から飛行マウントを呼び出すために、飛行マウントを無理矢理呼ぶ分岐も用意しておくと便利（4.0.1あたりでできるようになった）。
- 着替えMacro
#show [mod:ctrlshift]Mastery;[mod:shift]Fishing;[mod:ctrl]Cooking;[mod:alt]Dodge;Armor Skills
/equipset [spec:2,mod:ctrlshift]PvP2;[mod:ctrlshift]PvP1;[mod:shift]Fishing;[mod:ctrl]Cooking;[mod:alt]Naked;[spec:2,button:1][spec:1,button:2]spec2;spec1
Equipsetと修飾キーを使って1ボタンで装備を切り替えるMacro。このMacroを使うためにはEquipment Manager*6機能で予め必要な装備セットを登録しておく必要がある。上の例だと、PvE装備が表・裏用でそれぞれspec1/spec2、PvP装備がPvP1/PvP2、すべての装備を脱いだ状態がNaked（用意しておくと地味に便利）、Chef's Hatを装備するCooking、釣竿・釣り帽子・長靴などを装備するFishingが含まれているので、それらの装備セットを用意しておけば、あとは状況と修飾キーとで切り替えられる。#showはアイコンだけ変えてtooltipを替えないようにするコマンド。基本的にはマウスクリックで使用することを想定しており、右クリックすれば逆のスペック用の装備を着ることもできるようになっている。
- Range武器使用
#showtooltip
/startattack
/cast [equipped:Thrown,@mouseover,harm,nodead][equipped:Thrown]Throw;[noequipped:Thrown,@mouseover,harm,nodead][noequipped:Thrown]Shoot
投げ武器なら投げ、ほかなら撃つ。
- Healthstone（とMountspecial）
#showtooltip [nocombat,mounted,noflying]item:25653;item:5512
/mountspecial [mounted,noflying]
/use [nomounted]Healthstone
HealthstoneはCataで1つのitemIDに統一されたので、このようにitemIDを無理矢理入力することでバッグにHSがあってもなくても常にツールチップを出せる。このやり方はspellIDには残念ながら対応していない。ついでに暇な時にMountspecialを呼ぶボタンにしている（アイコンは昔のMountスピード上昇Trinket）。
- タレント変更
/usetalents [spec:1]2;1
こんなコマンドもある。
- Inspect
/inspect
気になるあいつの装備を見ようとして、間違ってinviteしてしまった！なんてことを防ぐ。ほかに/rollとかも作っておくと意外と便利。
- ものを数える
#showtooltip Elementium Ore
Use効果のないアイテムも、このように書くとバーの上に表示だけさせることができ、かつ、バッグ内にあるそのアイテムの総数を表示してくれる。Farm中とかに便利。
- ArgentTournamentのデイリークエスト（熊丘で蛙にキスするやつ）
#showtooltip
/use Warts-B-Gone Lip Balm
/tar [noexists]Lake Frog
/kiss
/cleartarget
これに限らず、よくやるデイリークエストの内容はMacroにしておくと楽なことがある。Macroスロットが余ってる人向け。
- 考古学集計
/run print("Total artifacts"); for x=1,9 do local c=GetNumArtifactsByRace(x); local a =0; for y=1,c do local t = select(9, GetArtifactInfoByRace(x, y)); a=a+t;end local rn = GetArchaeologyRaceInfo(x); if( c > 1 ) then print(rn .. ": " .. a); end end
ちょっと番外編気味。/runコマンドはluaスクリプトを無理矢理走らせるので、詳しい人はこれを使ってさらにいろいろ細かいことができてしまうらしい（私はコピペしてきたのを使うくらいだ）。このMacroだと、ArchaeologyでSolveしたプロジェクトの数をRaceごとに集計して表示する。
- カメラを最大望遠にする
/console cameraDistanceMax 50
番外編その2。こちら参照。
- CTC（Combat Table Coverage）チェッカー
/run DEFAULT_CHAT_FRAME:AddMessage("Need 102.4% for combat table coverage. Current buffed coverage: "..string.format("%.2f", GetDodgeChance()+GetBlockChance()+GetParryChance() +5).."%")
CTCとはWarrior及びPaladin Tankで、Block込みでボスのMelee攻撃が通常Hitしなくなる状態（いわゆるUnhittable）。これが達成されていると、Melee攻撃が悪くとも30%軽減（Block）される。T13では比較的容易に達成できるのでたいていの盾Tankはこれをまず目指す。上のスクリプトはDodge/Parry/Blockの合計に5%の固定Miss率を加えた数値を表示する。これが102.4%を上回ればOK。
- AHで、表示されているページの1番上の商品をBuyoutする
/run local top=GetAuctionItemInfo("list",1) if top then PlaceAuctionBid("list",1,select(10,GetAuctionItemInfo("list",1))) end
タイトルそのまんま。少量スタックで大量出品されているようなものを連続購入したい時なんかに使っている。確認ウィンドウが出ないので注意！！
- Raidターゲットマーカー
/tar Twilight Elite Dreadblade
/tar Hideous Amalgamation
/script SetRaidTarget("Target",8);
/targetlasttarget
/changeactionbar 1
SetRaidTarget関数は、ターゲットとマーカー番号を引数に取り、マーカーをつける頻出関数。マーカー番号は8がドクロ、7がバツ〜1が星印まで、メニューに出てくる順に並んでいる。/tarで重要な対象をターゲットし、マーカーを付けて、/targetlasttargetで直前のターゲットに戻る。ターゲットにはUnitID（Target/Focus/Raid1/Party1/Boss1等）のほか、Raidメンバーなら名前をそのまま入れることができる。ちなみにターゲットマーカーはPvPで敵プレイヤーにつけることはできないので、当然このようなMacroも敵プレイヤーに対しては動作しない。
